View source with formatted comments or as raw
    1/*  Part of SWI-Prolog
    2
    3    Author:        Jan Wielemaker
    4    E-mail:        J.Wielemaker@vu.nl
    5    WWW:           http://www.swi-prolog.org
    6    Copyright (c)  2004-2013, University of Amsterdam
    7                              VU University Amsterdam
    8    All rights reserved.
    9
   10    Redistribution and use in source and binary forms, with or without
   11    modification, are permitted provided that the following conditions
   12    are met:
   13
   14    1. Redistributions of source code must retain the above copyright
   15       notice, this list of conditions and the following disclaimer.
   16
   17    2. Redistributions in binary form must reproduce the above copyright
   18       notice, this list of conditions and the following disclaimer in
   19       the documentation and/or other materials provided with the
   20       distribution.
   21
   22    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
   23    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
   24    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
   25    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
   26    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
   27    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
   28    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
   29    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
   30    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   31    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
   32    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
   33    POSSIBILITY OF SUCH DAMAGE.
   34*/
   35
   36:- module(prolog_operator,
   37        [ push_operators/1,             % +List
   38          push_operators/2,             % +List, -Undo
   39          pop_operators/0,
   40          pop_operators/1,              % +Undo
   41          push_op/3                     % Precedence, Type, Name
   42        ]).   43
   44
   45/** <module> Manage operators
   46
   47Often, one wants to define operators to  improve the readibility of some
   48very specific code. Operators in Prolog  are global objects and changing
   49operators changes syntax and possible semantics of existing sources. For
   50this reason it is desirable  to   reset  operator declarations after the
   51code that needs them has been read.   This module defines a rather cruel
   52-but portable- method to do this.
   53
   54Usage:
   55
   56==
   57:- push_operators(
   58        [ op(900, fx, hello_world)
   59        , op(600, xf, *)
   60        ]).
   61
   62hello_world World :-
   63        ....
   64
   65:- pop_operators.
   66==
   67
   68While the above are for  source-code,   the  calls  push_operators/2 and
   69pop_operators/1 can be used  for  local   processing  where  it  is more
   70comfortable to carry the undo context around.
   71
   72NOTE: In recent versions of SWI-Prolog operators   are local to a module
   73and can be exported using the syntax   below.  This is not portable, but
   74otherwise a more structured approach for operator handling.
   75
   76==
   77:- module(mymodule,
   78          [ mypred/1,
   79            op(500, fx, myop)
   80          ]).
   81==
   82
   83@compat SWI-Prolog
   84*/
   85
   86:- thread_local
   87    operator_stack/1.   88:- '$notransact'(operator_stack/1).   89
   90:- meta_predicate
   91    push_operators(:),
   92    push_operators(:,-),
   93    push_op(+,+,:).   94
   95%!  push_operators(:New) is det.
   96%!  push_operators(:New, -Undo) is det.
   97%
   98%   Installs the operators from New, where New is a list of op(Prec,
   99%   Type, :Name). The modifications to the operator table are undone
  100%   in a matching call to pop_operators/0.
  101
  102push_operators(New, Undo) :-
  103    strip_module(New, Module, Ops0),
  104    tag_ops(Ops0, Module, Ops),
  105    undo_operators(Ops, Undo),
  106    set_operators(Ops).
  107
  108push_operators(New) :-
  109    push_operators(New, Undo),
  110    asserta(operator_stack(mark-Undo)).
  111
  112%!  push_op(+Precedence, +Type, :Name) is det.
  113%
  114%   As op/3, but this call must  appear between push_operators/1 and
  115%   pop_operators/0.  The  change  is   undone    by   the  call  to
  116%   pop_operators/0
  117
  118push_op(P, T, A) :-
  119    undo_operator(op(P,T,A), Undo),
  120    op(P, T, A),
  121    asserta(operator_stack(incremental-Undo)).
  122
  123%!  pop_operators is det.
  124%
  125%   Revert all changes to the operator table realised since the last
  126%   push_operators/1.
  127
  128pop_operators :-
  129    retract(operator_stack(Mark-Undo)),
  130    set_operators(Undo),
  131    Mark == mark,
  132    !.
  133
  134%!  pop_operators(+Undo) is det.
  135%
  136%   Reset operators as pushed by push_operators/2.
  137
  138pop_operators(Undo) :-
  139    set_operators(Undo).
  140
  141tag_ops([], _, []).
  142tag_ops([op(P,Tp,N0)|T0], M, [op(P,Tp,N)|T]) :-
  143    strip_module(M:N0, M1, N1),
  144    N = M1:N1,
  145    tag_ops(T0, M, T).
  146
  147set_operators([]).
  148set_operators([H|R]) :-
  149    set_operators(H),
  150    set_operators(R).
  151set_operators(op(P,T,A)) :-
  152    op(P, T, A).
  153
  154undo_operators([], []).
  155undo_operators([O0|T0], [U0|T]) :-
  156    undo_operator(O0, U0),
  157    undo_operators(T0, T).
  158
  159undo_operator(op(_P, T, N), op(OP, OT, N)) :-
  160    current_op(OP, OT, N),
  161    same_op_type(T, OT),
  162    !.
  163undo_operator(op(P, T, [H|R]), [OH|OT]) :-
  164    !,
  165    undo_operator(op(P, T, H), OH),
  166    undo_operator(op(P, T, R), OT).
  167undo_operator(op(_, _, []), []) :- !.
  168undo_operator(op(_P, T, N), op(0, T, N)).
  169
  170same_op_type(T, OT) :-
  171    op_type(T, Type),
  172    op_type(OT, Type).
  173
  174op_type(fx,  prefix).
  175op_type(fy,  prefix).
  176op_type(xfx, infix).
  177op_type(xfy, infix).
  178op_type(yfx, infix).
  179op_type(xf,  postfix).
  180op_type(yf,  postfix)