View source with formatted comments or as raw
    1/*  Part of SWI-Prolog
    2
    3    Author:        Jan Wielemaker
    4    E-mail:        J.Wielemaker@vu.nl
    5    WWW:           http://www.swi-prolog.org
    6    Copyright (c)  2002-2018, University of Amsterdam
    7                              VU University Amsterdam
    8    All rights reserved.
    9
   10    Redistribution and use in source and binary forms, with or without
   11    modification, are permitted provided that the following conditions
   12    are met:
   13
   14    1. Redistributions of source code must retain the above copyright
   15       notice, this list of conditions and the following disclaimer.
   16
   17    2. Redistributions in binary form must reproduce the above copyright
   18       notice, this list of conditions and the following disclaimer in
   19       the documentation and/or other materials provided with the
   20       distribution.
   21
   22    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
   23    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
   24    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
   25    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
   26    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
   27    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
   28    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
   29    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
   30    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   31    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
   32    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
   33    POSSIBILITY OF SUCH DAMAGE.
   34*/
   35
   36:- module(mimetype,
   37          [ file_mime_type/2,           % +Path, -Type
   38            file_content_type/2,        % +Path, -Type
   39            file_content_type/3         % +Path, ?MediaType, -Type
   40          ]).   41
   42/** <module> Determine mime-type for a file
   43
   44Simple library to guess the mime-type from   the extension of a file. As
   45various applications need  to  do  this   type  ofinferencing  it  seems
   46worthwhile to place this functionality in an extensible library.
   47
   48@tbd    Consider content handling (using the Unix file command)
   49@tbd    Allow parameters? (e.g. text/html; charset=UTF-8)
   50*/
   51
   52:- multifile
   53    mime:mime_extension/2,
   54    mime:text_mimetype/1,
   55    mime:charset/3.   56
   57%!  file_mime_type(+FileName, -MimeType) is semidet.
   58%
   59%   True when MimeType is  the  mime-type   to  be  used for sending
   60%   FileName. The default rules can be overridden and extended using
   61%   the hook mime:mime_extension/2.
   62%
   63%   @param MimeType is a compound term of the form Type/SubType.
   64
   65file_mime_type(File, MimeType) :-
   66    file_name_extension(_, Ext, File),
   67    (   current_prolog_flag(windows, true)
   68    ->  downcase_atom(Ext, Lower),
   69        mime_extension(Lower, MimeType)
   70    ;   mime_extension(Ext, M0)
   71    ->  MimeType = M0
   72    ;   downcase_atom(Ext, Lower),
   73        mime_extension(Lower, MimeType)
   74    ),
   75    !.
   76file_mime_type(File, MimeType) :-
   77    file_base_name(File, Base),
   78    downcase_atom(Base, Lower),
   79    name_mimetype(Lower, Mime),
   80    !,
   81    MimeType = Mime.
   82file_mime_type(_, MimeType) :-
   83    default_mimetype(MimeType).
   84
   85%!  mime:mime_extension(+Ext, -MimeType) is semidet.
   86%
   87%   Hook that is called by file_mime_type/2 before the default table
   88%   is examined.
   89
   90mime_extension(Ext, MimeType) :-
   91    (   mime:mime_extension(Ext, Mime)
   92    ->  MimeType = Mime
   93    ;   ext_mimetype(Ext, Mime)
   94    ->  MimeType = Mime
   95    ).
   96
   97%!  default_mimetype(-MimeType) is semidet.
   98%
   99%   If the mime-type cannot be determined   from the file extension,
  100%   this predicate is used as fallback.  It takes the value from the
  101%   Prolog flag =default_mimetype=. To change the default, use e.g.,
  102%
  103%     ==
  104%     :- set_prolog_flag(default_mimetype, text/plain).
  105%     ==
  106%
  107%   The initial default mime-type   is  =|application/unknown|=. Use
  108%   the value =|-|= to denote there is no default.
  109
  110:- create_prolog_flag(default_mimetype, application/unknown, [keep(true)]).  111
  112default_mimetype(MimeType) :-
  113    current_prolog_flag(default_mimetype, MimeType),
  114    MimeType = _/_.
  115
  116
  117%!  ext_mimetype(+Extension, -MimeType) is semidet.
  118%
  119%   Built-in table of file-name extension to mime-type mappings.
  120%
  121%   @tbd    Update this list, e.g., from
  122%           http://www.webmaster-toolkit.com/mime-types.shtml
  123
  124                                        % plain text
  125ext_mimetype(txt,  text/plain).
  126                                        % markup
  127ext_mimetype(htm,  text/html).
  128ext_mimetype(html, text/html).
  129ext_mimetype(xhtml, application/'xhtml+xml').
  130ext_mimetype(sgml, text/'x-sgml').
  131ext_mimetype(sgm,  text/'x-sgml').
  132ext_mimetype(xml,  text/xml).
  133ext_mimetype(css,  text/css).
  134ext_mimetype(xsl,  text/xml).           % Unclear what this should be.
  135ext_mimetype(md,   text/markdown).
  136                                        % Other data markup
  137ext_mimetype(json, application/json).
  138ext_mimetype(yaml, application/yaml).   % Not official
  139                                        % semantic web stuff
  140ext_mimetype(rdf,  application/'rdf+xml').
  141ext_mimetype(rdfs, application/'rdf+xml').
  142ext_mimetype(owl,  application/'rdf+xml').
  143ext_mimetype(ttl,  application/turtle).
  144ext_mimetype(nt,   application/'n-triples').
  145ext_mimetype(nq,   application/'n-quads').
  146                                        % Prolog source
  147ext_mimetype(pl,   text/plain).
  148                                        % Other languages
  149ext_mimetype(c,    text/'x-c').
  150ext_mimetype(h,    text/'x-c').
  151ext_mimetype(cc,   text/'x-c').
  152ext_mimetype(py,   text/'x-python').
  153ext_mimetype(java, text/'x-java').
  154ext_mimetype(sh,   text/plain).
  155                                        % Packaged formats
  156ext_mimetype(gz,   application/'x-gzip').
  157ext_mimetype(zip,  application/zip).
  158ext_mimetype(tgz,  application/'x-gtar').
  159                                        % Some document formats
  160ext_mimetype(pdf,  application/pdf).
  161ext_mimetype(doc,  application/msword).
  162                                        % Java classes
  163ext_mimetype(class, application/'octet-stream').
  164ext_mimetype(jar,  application/'x-java-archive').
  165                                        % JavaScript
  166ext_mimetype(js,   text/javascript).
  167                                        % Visual Basic Script :-(
  168ext_mimetype(vbs,  text/vbscript).
  169                                        % Some image formats
  170ext_mimetype(jpg,  image/jpeg).
  171ext_mimetype(jpeg, image/jpeg).
  172ext_mimetype(gif,  image/gif).
  173ext_mimetype(png,  image/png).
  174ext_mimetype(tif,  image/tiff).
  175ext_mimetype(tiff, image/tiff).
  176ext_mimetype(xpm,  image/'x-xpixmap').
  177ext_mimetype(ico,  image/'x-ico').
  178ext_mimetype(svg,  image/'svg+xml').
  179                                        % Google earth
  180ext_mimetype(kml,  application/'vnd.google-earth.kml+xml').
  181ext_mimetype(kmz,  application/'vnd.google-earth.kmz').
  182
  183                                        % Flash
  184ext_mimetype(swf,  application/'x-shockwave-flash').
  185ext_mimetype(flv,  video/'x-flv').
  186                                        % MP3
  187ext_mimetype(mp3,  audio/mpeg).
  188                                        % Downloads
  189ext_mimetype(rpm,  application/'x-rpm').
  190ext_mimetype(exe,  application/'x-executable').
  191
  192%!  name_mimetype(+DownCaseFileName, -MimeType) is semidet.
  193%
  194%   Determine the mime-type of files based on the entire filename.
  195
  196name_mimetype(makefile,       text/plain).
  197name_mimetype(configure,      text/plain).
  198name_mimetype('configure.in', text/plain).
  199name_mimetype('configure.ac', text/plain).
  200name_mimetype('makefile.in',  text/plain).
  201name_mimetype('makefile.am',  text/plain).
  202name_mimetype('readme.in',    text/plain).
  203
  204%!  text_mimetype(+MimeType) is semidet.
  205%
  206%   True when documents of MimeType are text documents and thus may need
  207%   a charset specification.
  208
  209text_mimetype(MimeType) :-
  210    mime:text_mimetype(MimeType),
  211    !.
  212text_mimetype(text/_).
  213
  214%!  file_content_type(+File:atom, -ContentType:atom) is det.
  215%!  file_content_type(+File:atom, ?MediaType, -ContentType:atom) is det.
  216%
  217%   True if File should be served using =|ContentType:|= ContentType. It
  218%   takes the following steps:
  219%
  220%     1. Determine the media type using file_mime_type/2, unless
  221%        already specified using file_content_type/3.
  222%     2. Determine it is a text file using text_mimetype/1
  223%     3. Use the charset from the Prolog flag `default_charset`
  224%
  225%   The behavior is controlled by several hooks and a flag.
  226%
  227%     - mime:mime_extension/2 defines the media type
  228%     - mime:text_mimetype/1 defines the media type is text
  229%     - mime:charset/3 derives the charset for a file with a given
  230%       media type, if the media type is text according to
  231%	mime:text_mimetype/1.
  232%     - If mime:text_mimetype/1 succeeds and mime:charset/3 fails, the
  233%       flag `default_charset` defines the charset unless it is set
  234%       to `-`.  The flag set by default to =UTF-8= if the Prolog
  235%       flag `encoding` is set to `utf8`.
  236
  237file_content_type(File, ContentType) :-
  238    file_content_type(File, _, ContentType).
  239file_content_type(File, MediaType, ContentType) :-
  240    (   ground(MediaType)
  241    ->  true
  242    ;   file_mime_type(File, MediaType)
  243    ),
  244    (   text_mimetype(MediaType),
  245        (   mime:charset(File, MediaType, Charset0)
  246        ->  Charset = Charset0
  247        ;   default_charset(Charset)
  248        )
  249    ->  format(atom(ContentType), '~w; charset=~w', [MediaType, Charset])
  250    ;   format(atom(ContentType), '~w', [MediaType])
  251    ).
  252
  253%!  mime:charset(+File, +MediaType, -Charset) is semidet.
  254%
  255%   Hook that determines the  Charset  for   File  that  has  media type
  256%   MediaType. This hook allows overruling file_content_type/2.
  257%
  258%   @see mime:text_mimetype/1.
  259
  260default_charset(Charset) :-
  261    current_prolog_flag(default_charset, Charset),
  262    Charset \== (-).
  263
  264set_default_charset :-
  265    current_prolog_flag(default_charset, _),
  266    !.
  267set_default_charset :-
  268    current_prolog_flag(encoding, utf8),
  269    !,
  270    set_prolog_flag(default_charset, 'UTF-8').
  271set_default_charset.
  272
  273:- initialization(set_default_charset).