View source with raw comments or as raw
    1/*  Part of SWI-Prolog
    2
    3    Author:        Jan Wielemaker
    4    E-mail:        J.Wielemaker@vu.nl
    5    WWW:           http://www.swi-prolog.org
    6    Copyright (c)  2003-2020, University of Amsterdam
    7                              VU University Amsterdam
    8                              CWI, Amsterdam
    9    All rights reserved.
   10
   11    Redistribution and use in source and binary forms, with or without
   12    modification, are permitted provided that the following conditions
   13    are met:
   14
   15    1. Redistributions of source code must retain the above copyright
   16       notice, this list of conditions and the following disclaimer.
   17
   18    2. Redistributions in binary form must reproduce the above copyright
   19       notice, this list of conditions and the following disclaimer in
   20       the documentation and/or other materials provided with the
   21       distribution.
   22
   23    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
   24    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
   25    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
   26    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
   27    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
   28    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
   29    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
   30    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
   31    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   32    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
   33    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
   34    POSSIBILITY OF SUCH DAMAGE.
   35*/
   36
   37:- module(make,
   38          [ make/0
   39          ]).   40:- autoload(library(apply),[maplist/2]).   41:- autoload(library(check),[list_undefined/0,list_void_declarations/0]).   42:- autoload(library(debug),[debug/3]).   43:- autoload(library(lists),[list_to_set/2,member/2]).   44:- autoload(library(option),[merge_options/3]).   45
   46
   47:- set_prolog_flag(generate_debug_info, false).

Reload modified source files

This module provides the SWI-Prolog `make' facility that synchronises Prolog internal database after loaded files have been edited.

bug
-
Dependency tracking is incomplete. Notably, there is no dependency tracking if compilation of one module depends on goal_expansion/2 or term_expansion/2 rules provided by another. */
   60:- multifile
   61    prolog:make_hook/2.
 make
Reload all source files that have been changed since they were loaded. This predicate peforms the following steps:
  1. Compute the set of files that need to be reloaded.
  2. Call the hook prolog:make_hook(before, Files)
  3. Reload the files
  4. Call the hook prolog:make_hook(after, Files)
  5. If (4) fails, call list_undefined/0.

The hooks are called with an empty list if no files need reloading.

   78make :-
   79    notrace(make_no_trace).
   80
   81make_no_trace :-
   82    '$update_library_index',
   83    findall(File, modified_file(File), Reload0),
   84    list_to_set(Reload0, Reload),
   85    (   prolog:make_hook(before, Reload)
   86    ->  true
   87    ;   true
   88    ),
   89    print_message(silent, make(reload(Reload))),
   90    maplist(reload_file, Reload),
   91    print_message(silent, make(done(Reload))),
   92    (   prolog:make_hook(after, Reload)
   93    ->  true
   94    ;   list_undefined,
   95        list_void_declarations
   96    ).
 modified_file(-File) is nondet
True when File is modified after it has been loaded.

(*) A file is considered modified if the modification time of the file is at least 1ms later that when it was loaded. The 1ms relaxed matching is used to compensate for inconsistent float handling and possible timing jitter.

See also
- https://github.com/SWI-Prolog/swipl-devel/issues/303
  109modified_file(File) :-
  110    source_file_property(Source, modified(Time)),
  111    \+ source_file_property(Source, included_in(_,_)),
  112    Time > 0.0,                     % See source_file/1
  113    (   source_file_property(Source, derived_from(File, LoadTime))
  114    ->  true
  115    ;   File = Source,
  116        LoadTime = Time
  117    ),
  118    (   catch(time_file(File, Modified), _, fail),
  119        Modified - LoadTime > 0.001             % (*)
  120    ->  true
  121    ;   source_file_property(Source, includes(Included, IncLoadTime)),
  122        catch(time_file(Included, Modified), _, fail),
  123        Modified - IncLoadTime > 0.001          % (*)
  124    ->  true
  125    ).
 reload_file(File)
Reload file into the proper module.
bug
- If modules import each other, we must load them in the proper order for import/export dependencies.
  135:- public reload_file/1.                % Used by PDT
  136
  137reload_file(File) :-
  138    source_base_name(File, Compile),
  139    findall(M-Opts,
  140            source_file_property(File, load_context(M, _, Opts)),
  141            Modules),
  142    (   Modules = [First-OptsFirst|Rest]
  143    ->  Extra = [ silent(false),
  144                  register(false)
  145                ],
  146        merge_options([if(true)|Extra], OptsFirst, OFirst),
  147        debug(make, 'Make: First load ~q', [load_files(First:Compile, OFirst)]),
  148        load_files(First:Compile, OFirst),
  149        forall(member(Context-Opts, Rest),
  150               ( merge_options([if(not_loaded)|Extra], Opts, O),
  151                 debug(make, 'Make: re-import: ~q',
  152                       [load_files(Context:Compile, O)]),
  153                 load_files(Context:Compile, O)
  154               ))
  155    ;   load_files(user:Compile)
  156    ).
  157
  158source_base_name(File, Compile) :-
  159    file_name_extension(Compile, Ext, File),
  160    user:prolog_file_type(Ext, prolog),
  161    !.
  162source_base_name(File, File).
 prolog:make_hook(+When, +Files) is semidet
This hook is called by make/0. It is called with the following values for When:
before
The hook is called before reloading starts. The default action is to do nothing.
after
The hook is called after reloading completed. The default action is to call list_undefined/1 as:
list_undefined([scan(local)]).

The hook can be used to change program validation, stop or restart services, etc.

Arguments:
Files- is a list holding the canonical file names of the files that need to be reloaded. This list can be empty.