View source with raw comments or as raw
    1/*  Part of SWI-Prolog
    2
    3    Author:        Jan Wielemaker and Jon Jagger
    4    E-mail:        J.Wielemaker@vu.nl
    5    WWW:           http://www.swi-prolog.org
    6    Copyright (c)  2001-2021, University of Amsterdam
    7                              VU University Amsterdam
    8                              SWI-Prolog Solutions b.v.
    9    All rights reserved.
   10
   11    Redistribution and use in source and binary forms, with or without
   12    modification, are permitted provided that the following conditions
   13    are met:
   14
   15    1. Redistributions of source code must retain the above copyright
   16       notice, this list of conditions and the following disclaimer.
   17
   18    2. Redistributions in binary form must reproduce the above copyright
   19       notice, this list of conditions and the following disclaimer in
   20       the documentation and/or other materials provided with the
   21       distribution.
   22
   23    THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
   24    "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
   25    LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
   26    FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
   27    COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
   28    INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
   29    BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
   30    LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
   31    CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
   32    LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
   33    ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
   34    POSSIBILITY OF SUCH DAMAGE.
   35*/
   36
   37:- module(ordsets,
   38          [ is_ordset/1,                % @Term
   39            list_to_ord_set/2,          % +List, -OrdSet
   40            ord_add_element/3,          % +Set, +Element, -NewSet
   41            ord_del_element/3,          % +Set, +Element, -NewSet
   42            ord_selectchk/3,            % +Item, ?Set1, ?Set2
   43            ord_intersect/2,            % +Set1, +Set2 (test non-empty)
   44            ord_intersect/3,            % +Set1, +Set2, -Intersection
   45            ord_intersection/3,         % +Set1, +Set2, -Intersection
   46            ord_intersection/4,         % +Set1, +Set2, -Intersection, -Diff
   47            ord_disjoint/2,             % +Set1, +Set2
   48            ord_subtract/3,             % +Set, +Delete, -Remaining
   49            ord_union/2,                % +SetOfOrdSets, -Set
   50            ord_union/3,                % +Set1, +Set2, -Union
   51            ord_union/4,                % +Set1, +Set2, -Union, -New
   52            ord_subset/2,               % +Sub, +Super (test Sub is in Super)
   53                                        % Non-Quintus extensions
   54            ord_empty/1,                % ?Set
   55            ord_memberchk/2,            % +Element, +Set,
   56            ord_symdiff/3,              % +Set1, +Set2, ?Diff
   57                                        % SICSTus extensions
   58            ord_seteq/2,                % +Set1, +Set2
   59            ord_intersection/2          % +PowerSet, -Intersection
   60          ]).   61:- set_prolog_flag(generate_debug_info, false).

Ordered set manipulation

Ordered sets are lists with unique elements sorted to the standard order of terms (see sort/2). Exploiting ordering, many of the set operations can be expressed in order N rather than N^2 when dealing with unordered sets that may contain duplicates. The library(ordsets) is available in a number of Prolog implementations. Our predicates are designed to be compatible with common practice in the Prolog community. The implementation is incomplete and relies partly on library(oset), an older ordered set library distributed with SWI-Prolog. New applications are advised to use library(ordsets).

Some of these predicates match directly to corresponding list operations. It is advised to use the versions from this library to make clear you are operating on ordered sets. An exception is member/2. See ord_memberchk/2.

The ordsets library is based on the standard order of terms. This implies it can handle all Prolog terms, including variables. Note however, that the ordering is not stable if a term inside the set is further instantiated. Also note that variable ordering changes if variables in the set are unified with each other or a variable in the set is unified with a variable that is `older' than the newest variable in the set. In practice, this implies that it is allowed to use member(X, OrdSet) on an ordered set that holds variables only if X is a fresh variable. In other cases one should cease using it as an ordset because the order it relies on may have been changed. */

 is_ordset(@Term) is semidet
True if Term is an ordered set. All predicates in this library expect ordered sets as input arguments. Failing to fullfil this assumption results in undefined behaviour. Typically, ordered sets are created by predicates from this library, sort/2 or setof/3.
  100is_ordset(Term) :-
  101    is_list(Term),
  102    is_ordset2(Term).
  103
  104is_ordset2([]).
  105is_ordset2([H|T]) :-
  106    is_ordset3(T, H).
  107
  108is_ordset3([], _).
  109is_ordset3([H2|T], H) :-
  110    H2 @> H,
  111    is_ordset3(T, H2).
 ord_empty(?List) is semidet
True when List is the empty ordered set. Simply unifies list with the empty list. Not part of Quintus.
  119ord_empty([]).
 ord_seteq(+Set1, +Set2) is semidet
True if Set1 and Set2 have the same elements. As both are canonical sorted lists, this is the same as ==/2.
Compatibility
- sicstus
  129ord_seteq(Set1, Set2) :-
  130    Set1 == Set2.
 list_to_ord_set(+List, -OrdSet) is det
Transform a list into an ordered set. This is the same as sorting the list.
  138list_to_ord_set(List, Set) :-
  139    sort(List, Set).
 ord_intersect(+Set1, +Set2) is semidet
True if both ordered sets have a non-empty intersection.
  146ord_intersect([H1|T1], L2) :-
  147    ord_intersect_(L2, H1, T1).
  148
  149ord_intersect_([H2|T2], H1, T1) :-
  150    compare(Order, H1, H2),
  151    ord_intersect__(Order, H1, T1, H2, T2).
  152
  153ord_intersect__(<, _H1, T1,  H2, T2) :-
  154    ord_intersect_(T1, H2, T2).
  155ord_intersect__(=, _H1, _T1, _H2, _T2).
  156ord_intersect__(>, H1, T1,  _H2, T2) :-
  157    ord_intersect_(T2, H1, T1).
 ord_disjoint(+Set1, +Set2) is semidet
True if Set1 and Set2 have no common elements. This is the negation of ord_intersect/2.
  165ord_disjoint(Set1, Set2) :-
  166    \+ ord_intersect(Set1, Set2).
 ord_intersect(+Set1, +Set2, -Intersection)
Intersection holds the common elements of Set1 and Set2.
deprecated
- Use ord_intersection/3
  175ord_intersect(Set1, Set2, Intersection) :-
  176    ord_intersection(Set1, Set2, Intersection).
 ord_intersection(+PowerSet, -Intersection)
Intersection of a powerset. True when Intersection is an ordered set holding all elements common to all sets in PowerSet.
Compatibility
- sicstus
  186ord_intersection(PowerSet, Intersection) :-
  187    key_by_length(PowerSet, Pairs),
  188    keysort(Pairs, [_-S|Sorted]),
  189    l_int(Sorted, S, Intersection).
  190
  191key_by_length([], []).
  192key_by_length([H|T0], [L-H|T]) :-
  193    length(H, L),
  194    key_by_length(T0, T).
  195
  196l_int([], S, S).
  197l_int([_-H|T], S0, S) :-
  198    ord_intersection(S0, H, S1),
  199    l_int(T, S1, S).
 ord_intersection(+Set1, +Set2, -Intersection) is det
Intersection holds the common elements of Set1 and Set2. Uses ord_disjoint/2 if Intersection is bound to [] on entry.
  207ord_intersection(Set1, Set2, Intersection) :-
  208    (   Intersection == []
  209    ->  ord_disjoint(Set1, Set2)
  210    ;   ord_intersection_(Set1, Set2, Intersection)
  211    ).
  212
  213ord_intersection_([], _Int, []).
  214ord_intersection_([H1|T1], L2, Int) :-
  215    isect2(L2, H1, T1, Int).
  216
  217isect2([], _H1, _T1, []).
  218isect2([H2|T2], H1, T1, Int) :-
  219    compare(Order, H1, H2),
  220    isect3(Order, H1, T1, H2, T2, Int).
  221
  222isect3(<, _H1, T1,  H2, T2, Int) :-
  223    isect2(T1, H2, T2, Int).
  224isect3(=, H1, T1, _H2, T2, [H1|Int]) :-
  225    ord_intersection_(T1, T2, Int).
  226isect3(>, H1, T1,  _H2, T2, Int) :-
  227    isect2(T2, H1, T1, Int).
 ord_intersection(+Set1, +Set2, ?Intersection, ?Difference) is det
Intersection and difference between two ordered sets. Intersection is the intersection between Set1 and Set2, while Difference is defined by ord_subtract(Set2, Set1, Difference).
See also
- ord_intersection/3 and ord_subtract/3.
  238ord_intersection([], L, [], L) :- !.
  239ord_intersection([_|_], [], [], []) :- !.
  240ord_intersection([H1|T1], [H2|T2], Intersection, Difference) :-
  241    compare(Diff, H1, H2),
  242    ord_intersection2(Diff, H1, T1, H2, T2, Intersection, Difference).
  243
  244ord_intersection2(=, H1, T1, _H2, T2, [H1|T], Difference) :-
  245    ord_intersection(T1, T2, T, Difference).
  246ord_intersection2(<, _, T1, H2, T2, Intersection, Difference) :-
  247    ord_intersection(T1, [H2|T2], Intersection, Difference).
  248ord_intersection2(>, H1, T1, H2, T2, Intersection, [H2|HDiff]) :-
  249    ord_intersection([H1|T1], T2, Intersection, HDiff).
 ord_add_element(+Set1, +Element, ?Set2) is det
Insert an element into the set. This is the same as ord_union(Set1, [Element], Set2).
  257ord_add_element([], El, [El]).
  258ord_add_element([H|T], El, Add) :-
  259    compare(Order, H, El),
  260    addel(Order, H, T, El, Add).
  261
  262addel(<, H, T,  El, [H|Add]) :-
  263    ord_add_element(T, El, Add).
  264addel(=, H, T, _El, [H|T]).
  265addel(>, H, T,  El, [El,H|T]).
 ord_del_element(+Set, +Element, -NewSet) is det
Delete an element from an ordered set. This is the same as ord_subtract(Set, [Element], NewSet).
  274ord_del_element([], _El, []).
  275ord_del_element([H|T], El, Del) :-
  276    compare(Order, H, El),
  277    delel(Order, H, T, El, Del).
  278
  279delel(<,  H, T,  El, [H|Del]) :-
  280    ord_del_element(T, El, Del).
  281delel(=, _H, T, _El, T).
  282delel(>,  H, T, _El, [H|T]).
 ord_selectchk(+Item, ?Set1, ?Set2) is semidet
Selectchk/3, specialised for ordered sets. Is true when select(Item, Set1, Set2) and Set1, Set2 are both sorted lists without duplicates. This implementation is only expected to work for Item ground and either Set1 or Set2 ground. The "chk" suffix is meant to remind you of memberchk/2, which also expects its first argument to be ground. ord_selectchk(X, S, T) => ord_memberchk(X, S) & \+ ord_memberchk(X, T).
author
- Richard O'Keefe
  297ord_selectchk(Item, [X|Set1], [X|Set2]) :-
  298    X @< Item,
  299    !,
  300    ord_selectchk(Item, Set1, Set2).
  301ord_selectchk(Item, [Item|Set1], Set1) :-
  302    (   Set1 == []
  303    ->  true
  304    ;   Set1 = [Y|_]
  305    ->  Item @< Y
  306    ).
 ord_memberchk(+Element, +OrdSet) is semidet
True if Element is a member of OrdSet, compared using ==. Note that enumerating elements of an ordered set can be done using member/2.

Some Prolog implementations also provide ord_member/2, with the same semantics as ord_memberchk/2. We believe that having a semidet ord_member/2 is unacceptably inconsistent with the *_chk convention. Portable code should use ord_memberchk/2 or member/2.

author
- Richard O'Keefe
  323ord_memberchk(Item, [X1,X2,X3,X4|Xs]) :-
  324    !,
  325    compare(R4, Item, X4),
  326    (   R4 = (>) -> ord_memberchk(Item, Xs)
  327    ;   R4 = (<) ->
  328        compare(R2, Item, X2),
  329        (   R2 = (>) -> Item == X3
  330        ;   R2 = (<) -> Item == X1
  331        ;/* R2 = (=),   Item == X2 */ true
  332        )
  333    ;/* R4 = (=) */ true
  334    ).
  335ord_memberchk(Item, [X1,X2|Xs]) :-
  336    !,
  337    compare(R2, Item, X2),
  338    (   R2 = (>) -> ord_memberchk(Item, Xs)
  339    ;   R2 = (<) -> Item == X1
  340    ;/* R2 = (=) */ true
  341    ).
  342ord_memberchk(Item, [X1]) :-
  343    Item == X1.
 ord_subset(+Sub, +Super) is semidet
Is true if all elements of Sub are in Super
  350ord_subset([], _).
  351ord_subset([H1|T1], [H2|T2]) :-
  352    compare(Order, H1, H2),
  353    ord_subset_(Order, H1, T1, T2).
  354
  355ord_subset_(>, H1, T1, [H2|T2]) :-
  356    compare(Order, H1, H2),
  357    ord_subset_(Order, H1, T1, T2).
  358ord_subset_(=, _, T1, T2) :-
  359    ord_subset(T1, T2).
 ord_subtract(+InOSet, +NotInOSet, -Diff) is det
Diff is the set holding all elements of InOSet that are not in NotInOSet.
  367ord_subtract([], _Not, []).
  368ord_subtract([H1|T1], L2, Diff) :-
  369    diff21(L2, H1, T1, Diff).
  370
  371diff21([], H1, T1, [H1|T1]).
  372diff21([H2|T2], H1, T1, Diff) :-
  373    compare(Order, H1, H2),
  374    diff3(Order, H1, T1, H2, T2, Diff).
  375
  376diff12([], _H2, _T2, []).
  377diff12([H1|T1], H2, T2, Diff) :-
  378    compare(Order, H1, H2),
  379    diff3(Order, H1, T1, H2, T2, Diff).
  380
  381diff3(<,  H1, T1,  H2, T2, [H1|Diff]) :-
  382    diff12(T1, H2, T2, Diff).
  383diff3(=, _H1, T1, _H2, T2, Diff) :-
  384    ord_subtract(T1, T2, Diff).
  385diff3(>,  H1, T1, _H2, T2, Diff) :-
  386    diff21(T2, H1, T1, Diff).
 ord_union(+SetOfSets, -Union) is det
True if Union is the union of all elements in the superset SetOfSets. Each member of SetOfSets must be an ordered set, the sets need not be ordered in any way.
author
- Copied from YAP, probably originally by Richard O'Keefe.
  397ord_union([], Union) =>
  398    Union = [].
  399ord_union([Set|Sets], Union) =>
  400    length([Set|Sets], NumberOfSets),
  401    ord_union_all(NumberOfSets, [Set|Sets], Union, []).
  402
  403ord_union_all(N, Sets0, Union, Sets) =>
  404    (   N =:= 1
  405    ->  Sets0 = [Union|Sets]
  406    ;   N =:= 2
  407    ->  Sets0 = [Set1,Set2|Sets],
  408        ord_union(Set1,Set2,Union)
  409    ;   A is N>>1,
  410        Z is N-A,
  411        ord_union_all(A, Sets0, X, Sets1),
  412        ord_union_all(Z, Sets1, Y, Sets),
  413        ord_union(X, Y, Union)
  414    ).
 ord_union(+Set1, +Set2, -Union) is det
Union is the union of Set1 and Set2
  421ord_union([], Set2, Union) =>
  422    Union = Set2.
  423ord_union([H1|T1], L2, Union) =>
  424    union2(L2, H1, T1, Union).
  425
  426union2([], H1, T1, Union) =>
  427    Union = [H1|T1].
  428union2([H2|T2], H1, T1, Union) =>
  429    compare(Order, H1, H2),
  430    union3(Order, H1, T1, H2, T2, Union).
  431
  432union3(<, H1, T1,  H2, T2, Union) =>
  433    Union = [H1|Union0],
  434    union2(T1, H2, T2, Union0).
  435union3(=, H1, T1, _H2, T2, Union) =>
  436    Union = [H1|Union0],
  437    ord_union(T1, T2, Union0).
  438union3(>, H1, T1,  H2, T2, Union) =>
  439    Union = [H2|Union0],
  440    union2(T2, H1, T1, Union0).
 ord_union(+Set1, +Set2, -Union, -New) is det
True iff ord_union(Set1, Set2, Union) and ord_subtract(Set2, Set1, New).
  447ord_union([], Set2, Set2, Set2).
  448ord_union([H|T], Set2, Union, New) :-
  449    ord_union_1(Set2, H, T, Union, New).
  450
  451ord_union_1([], H, T, [H|T], []).
  452ord_union_1([H2|T2], H, T, Union, New) :-
  453    compare(Order, H, H2),
  454    ord_union(Order, H, T, H2, T2, Union, New).
  455
  456ord_union(<, H, T, H2, T2, [H|Union], New) :-
  457    ord_union_2(T, H2, T2, Union, New).
  458ord_union(>, H, T, H2, T2, [H2|Union], [H2|New]) :-
  459    ord_union_1(T2, H, T, Union, New).
  460ord_union(=, H, T, _, T2, [H|Union], New) :-
  461    ord_union(T, T2, Union, New).
  462
  463ord_union_2([], H2, T2, [H2|T2], [H2|T2]).
  464ord_union_2([H|T], H2, T2, Union, New) :-
  465    compare(Order, H, H2),
  466    ord_union(Order, H, T, H2, T2, Union, New).
 ord_symdiff(+Set1, +Set2, ?Difference) is det
Is true when Difference is the symmetric difference of Set1 and Set2. I.e., Difference contains all elements that are not in the intersection of Set1 and Set2. The semantics is the same as the sequence below (but the actual implementation requires only a single scan).
      ord_union(Set1, Set2, Union),
      ord_intersection(Set1, Set2, Intersection),
      ord_subtract(Union, Intersection, Difference).

For example:

?- ord_symdiff([1,2], [2,3], X).
X = [1,3].
  490ord_symdiff([], Set2, Set2).
  491ord_symdiff([H1|T1], Set2, Difference) :-
  492    ord_symdiff(Set2, H1, T1, Difference).
  493
  494ord_symdiff([], H1, T1, [H1|T1]).
  495ord_symdiff([H2|T2], H1, T1, Difference) :-
  496    compare(Order, H1, H2),
  497    ord_symdiff(Order, H1, T1, H2, T2, Difference).
  498
  499ord_symdiff(<, H1, Set1, H2, T2, [H1|Difference]) :-
  500    ord_symdiff(Set1, H2, T2, Difference).
  501ord_symdiff(=, _, T1, _, T2, Difference) :-
  502    ord_symdiff(T1, T2, Difference).
  503ord_symdiff(>, H1, T1, H2, Set2, [H2|Difference]) :-
  504    ord_symdiff(Set2, H1, T1, Difference)